From 3688caa2eddaefddde4cfa66fa08853c332a84fc Mon Sep 17 00:00:00 2001
From: Fabian Keil <fk@fabiankeil.de>
Date: Sun, 15 May 2016 12:09:26 +0200
Subject: [PATCH 210/257] Add geli-request-monitor.d

... which shows the BIO commands GELI received and their
lengths from the caller's point of view.

Obtained from: ElectroBSD
---
 share/dtrace/geli-request-monitor.d | 86 +++++++++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100755 share/dtrace/geli-request-monitor.d

diff --git a/share/dtrace/geli-request-monitor.d b/share/dtrace/geli-request-monitor.d
new file mode 100755
index 000000000000..c306d15bff96
--- /dev/null
+++ b/share/dtrace/geli-request-monitor.d
@@ -0,0 +1,86 @@
+#!/usr/sbin/dtrace -s
+
+/***************************************************************************
+ * geli-request-monitor
+ *
+ * Shows the length distribution of various GELI commands from
+ * the callers point of view (that is, without geli overhead).
+ *
+ * Copyright (c) 2016 Fabian Keil <fk@fabiankeil.de>
+ *
+ * Permission to use, copy, modify, and distribute this software for any
+ * purpose with or without fee is hereby granted, provided that the above
+ * copyright notice and this permission notice appear in all copies.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+ * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+ * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+ * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+ * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+ * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+ * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+ ***************************************************************************/
+
+#pragma D option quiet
+
+dtrace:::BEGIN
+{
+        bio_command[0x01] = "BIO_READ";
+        bio_command[0x02] = "BIO_WRITE";
+        bio_command[0x04] = "BIO_DELETE";
+        bio_command[0x08] = "BIO_GETATTR";
+        bio_command[0x10] = "BIO_FLUSH";
+        bio_command[0x20] = "BIO_CMD0";
+        bio_command[0x40] = "BIO_CMD1";
+        bio_command[0x80] = "BIO_CMD2";
+}
+
+
+fbt::g_eli_crypto_run:entry
+{
+        this->bp = (struct bio *)arg1;
+        this->sc = (struct g_eli_softc *)this->bp->bio_to->geom->softc;
+
+        this->geom_name = stringof(this->sc->sc_geom->name);
+        this->length = this->bp->bio_length;
+        this->inflight = this->sc->sc_inflight;
+
+        this->bio_command = (bio_command[this->bp->bio_cmd] != NULL) ?
+            bio_command[this->bp->bio_cmd] : "Unregistered command";
+
+        @inflight_max[this->geom_name] = max(this->inflight);
+        @inflight_max_total[this->geom_name] = max(this->inflight);
+
+        @length[this->geom_name, this->bio_command] =
+            lquantize(this->length, 4096, 172032, 4096);
+        @length_total[this->geom_name, this->bio_command] =
+            lquantize(this->length, 4096,  172032, 4096);
+/*
+        printf("%s: Length: %d, Inflight: %d", this->bio_command,
+            this->length, this->inflight);
+*/
+
+        stats_available = 1;
+}
+
+tick-60s
+/stats_available/
+{
+        printf("------------------------------\n");
+        printa(@inflight_max);
+        printa(@length);
+        trunc(@length);
+        trunc(@inflight_max);
+        stats_available = 0;
+}
+
+END
+{
+        /* Explicitly ditch interval stats so they aren't printed */
+        trunc(@length);
+        trunc(@inflight_max);
+
+        printf("\n------------------------------\n");
+        printa(@inflight_max_total);
+        printa(@length_total);
+}
-- 
2.11.0